1' FOR THE THINKJET PRINTER IN HP MODE
2 'BY WELDON MCKEE 27 JAN 85
3 'MODIFIED AT LINE 1000 12 JULY 85
5 GOSUB1000:FORX=1TO500:NEXT
7 IFA<>2THENPRINT:PRINT "TO CONTINUE, PUT THE PRINTER ON LINE!":PRINT "       THEN HIT F4 TO RUN.":PRINT:STOP
10 CLS:PRINT@166,"HP Thinkjet Printer Settings":FORX=1TO500:NEXT:CLS
20 PRINT"Choose Which Ones":PRINT
40 PRINTTAB(3)"1. Normal Pitch     4. Exp-comp"
50 PRINTTAB(3)"2. Expanded Pitch   5. Perf. Skip"
60 PRINTTAB(3)"3. Compressed Pitch 6. Reset"
65 PRINTTAB(3)"7. Wraparound on    8. Bold mode on"
67 PRINTTAB(12)"9. Exit-Menu"
70 A$=INKEY$:IFA$=""THEN70
80 B=VAL(A$):ONBGOSUB100,200,300,400,500,600,700,800,900
90 CLS:PRINT@174,"PRINTER SET"
95 FOR X=1TO500:NEXT:CLS:GOTO20
99 END
100 'NORMAL
110 LPRINTCHR$(27);CHR$(38);CHR$(107);CHR$(48);CHR$(83)
120 RETURN
200 'EXPANDED
210 LPRINTCHR$(27);CHR$(38);CHR$(107);CHR$(49);CHR$(83)
220 RETURN
300 'COMPRESSED
310 LPRINTCHR$(27);CHR$(38);CHR$(107);CHR$(50);CHR$(83)
320 RETURN
400 'EXPANDED-COMPRESSED
410 LPRINTCHR$(27);CHR$(38);CHR$(107);CHR$(51);CHR$(83)
420 RETURN
500 'PERFORATION SKIP ON
510 LPRINTCHR$(27);CHR$(38);CHR$(108);CHR$(49);CHR$(76)
520 RETURN
600 'RESET PRINTER
610 LPRINTCHR$(27);CHR$(69)
620 RETURN
700 'ENABLE WRAPAROUND
710 LPRINTCHR$(27);CHR$(38);CHR$(115);CHR$(48);CHR$(67)
720 RETURN
800 'BOLD MODE ON
810 LPRINTCHR$(14)
820 RETURN
900 CLS:MENU
1000 REM
1005 CLS
1010 A=INP(187)AND6
1020 IFA=2THENPRINT"PRINTER READY":PRINT:GOTO 1040
1030 IFA<>2THENPRINT"H-P THINKJET PRINTER OFF LINE!"
1035 BEEP:FORX=1TO100:NEXT:BEEP
1040 RETURN
                                                                   