10 CLS:BEEP:'  'RAMDIR.BA' RAM DIRECTORY    PORTABLE 100 MAGAZINE 11/84 P 54
15 PRINT@126,"WILL PRINT RAM DIRECTORY":FOR T=1TO400:NEXT:' ADDED by S KENDALL
20 CLEAR200::'Ronald F. Balonis 7/1/84
30 DEFINTI-M:F$="":DIM F$(20),F(20)
40 TLE$="+++ RAM File Directory +++"
50 NO$="[\    \.\\] = ##### ":FO$=""
100 CLS:PRINT@7,TLE$::'-- SIGN ON
105 FX$=CHR$(192):FY$="DO"
110 X=VARPTR(FO$):POKE X,240
115 POKE X+1,174:POKE X+2,249:I=0
120 I=INSTR(I+1,FO$,FX$)
125 IFI=0THEN160
130 F$=MID$(FO$,I+1,10)
135 IFMID$(F$,9,2)=FY$THEN 140ELSE120
140 II=II+1:F$(II)=F$
145 IL=ASC(MID$(F$(II),1,1))
150 IH=ASC(MID$(F$(II),2,1))
155 F(II)=256*IH+IL:GOTO120
160 IFFX$=CHR$(128)THEN200
165 FX$=CHR$(128):FY$="BA":GOTO110
200 M=II::'--Rank Files
210 M=M/2:IFM<=0THEN300
220 FORJ=1TOII-M:IJ=J
230 IM=IJ+M
240 IFF(IM)>=F(IJ)THEN290
250 F=F(IJ):F$=F$(IJ)
260 F(IJ)=F(IM):F$(IJ)=F$(IM)
270 F(IM)=F:F$(IM)=F$
280 IJ=IJ-M:IFIJ>=1THEN230
290 NEXTJ:GOTO210
300 IL=ASC(MID$(F$(II),1,1))::'find end
310 IH=ASC(MID$(F$(II),2,1))::'of last
320 FX$=CHR$(0)+CHR$(0)+CHR$(0)
330 IFMID$(F$(II),9,2)="DO"THENFX$=CHR$(26)
400 FORXI=IH*256+ILTO HIMEM STEP240
410 IH=XI/256:IL=XI-IH*256
420 X=VARPTR(FO$):POKE X,240
430 POKE X+1,IL:POKE X+2,IH
440 I=INSTR(FO$,FX$):IFI=0THEN 460
450 F(II+1)=I+XI+LEN(FX$)-1:XI=HIMEM
460 NEXT XI
500 I1=1:I2=10:IF II<=10 THEN I2=II
505 CLS:PRINT@7,TLE$::'Ram Dir
510 FORI=I1TOI2
515 F$=MID$(F$(I),3,6)
520 FY$=RIGHT$(F$(I),2)
525 PRINTUSING NO$;F$;FY$;F(I+1)-F(I);
530 NEXTI:PRINT
535 PRINT@288,"++++ Press Spacebar ++++";
540 IFINKEY$=""THEN540
545 IFI=II+1THENMENU
550 I1=I:I2=II:GOTO505