10 CLS:PRINT:PRINTTAB(15)"BOND 007"
20 PRINTTAB(15)"========":DEFINTA
40 PRINT:DIMA(100,4),Q(10),L$(10)
50 FORT=0TOVAL(RIGHT$(TIME$,2)):R=RND(1):NEXT
90 PRINT"Do you want instructions? ";:Q$=INPUT$(1)
100 IFQ$="Y"ORQ$="y"THENGOSUB8000
120 PRINT:PRINT"Working... back in a minute"
140 '   Set up matrix
150 DATA LONDON,PARIS,ROME,NEW YORK,TOKYO,ISTANBUL,HONGKONG,CARACAS,BERLIN,MOSCOW
180 FORX=1TO10:READL$(X):NEXT
220 '  Place secret plans
230 P=INT(RND(1)*100)+1:A(P,3)=P
240 '  Two know where they are
250 Z=3:FORX=1TO2:GOSUB9000
260 Q(X)=A:A(A,3)=P:NEXT
270 '  Six know who knows
280 FORB=1TO2:FORY=1TO3:GOSUB9000
290 A(A,3)=Q(B):X=X+1:Q(X)=A:NEXT:NEXT
300 '  Sixteen think they know
310 FORY=1TO2:FORX=1TO8:GOSUB9000
320 A(A,3)=Q(X):NEXT:NEXT
340 FORX=1TO100:IFRND(1)>.8THEN360
350 IFA(X,3)=0THENA(X,3)=INT(RND(1)*100)+1
360 A(X,4)=INT(RND(1)*10)+1'  Location
370 IFRND(1)>.1THENA(X,1)=1'  Sex
380 IFRND(1)>.3THENA(X,2)=INT(RND(1)*4)+1'  Nationality
390 NEXT
450 CLS:PRINT:PRINT"Right 007 - find those plans and bring  them back!"
460 PRINT"I suggest you call on our agent #";
470 FORA=1TO100:IFA(A,2)<>1THENNEXT
475 PRINTA:PRINT" in "L$(A(A,4))" - he appears to be"
480 FORX=1TO3:P$=P$+CHR$(INT(RND(1)*26)+65):NEXTX
490 PRINT"in some danger. The password is "P$".":GOSUB8500:PRINT
510 PRINT"Oh - and SOME of the agents in London   right now (British and foreign) are -"
530 L=1:Z=1:S=10000:GOSUB9540
540 PRINT"DO YOU WANT A PRNTED CHECK LIST?"
550 Q$=INPUT$(1):IFQ$<>"Y"ANDQ$<>"y"THEN1000
560 PRINT"IS PRINTER ATTACHED AND READY?"
570 Q$=INPUT$(1):IFQ$<>"Y"ANDQ$<>"y"THEN1000
580 FORX=1TO4:LPRINT"AGENT.  LOC'N.  TIP";
600 LPRINTTAB(X*20);:NEXTX:LPRINT
610 FORX=1TO25:FORY=0TO3
630 LPRINTTAB(20*Y);X+25*Y;
640 NEXTY:LPRINT:NEXTX
999 '  Main game loop
1000 GOSUB8500:GOTO1200
1010 INPUT"Where to, James";Q$
1020 FORL1=1TO10:IFQ$=L$(L1)THEN1070
1030 NEXTL1
1040 PRINT"No place called "Q$" in the game."
1050 PRINT"I don't think you've typed properly.":S=S-10:GOTO1010
1070 IFL1=LTHEN1130
1080 IFRND(0)>.1THEN1130
1090 PRINT"The aircraft was sabotaged and blew up  in flight!"
1100 IFRND(0)<.4THEN1640
1120 PRINT"However, you were not on it!"
1130 FORXX=1TO1000:NEXT:PRINT"You're now in ";L$(L1);:L=L1:S=S-100
1140 IFRND(1)>.1THEN1200
1150 PRINT"There's a message from M in London.":GOSUB8500
1160 R=INT(RND(1)*100)+1:IFA(R,1)>10THEN1160
1170 A(R,1)=99:Z=A(R,4):PRINT"Message reads -"
1180 GOSUB9570:PRINT" AGENT #"R"IN "L$(Z);
1190 PRINT" HAS BEEN FOUND MURDERED."
1192 IFP<>RTHENPRINT"Message ends.":GOTO1200
1194 PRINT"PLANS WERE ON BODY. RETURN TO LONDON.":GOTO1640
1200 PRINT:PRINT"You are still in "L$(L)
1210 INPUT"Your contact #";C1:S=S-2:IFC1=0THEN1010
1220 IFC1>100THENPRINT"TOO HIGH!":GOTO1210
1230 IFC=C1THENGOSUB9340:S=S-5:PRINT"just left.":GOTO1140
1240 IFA(C1,1)>10THENGOSUB9340:PRINT"is dead!":GOTO1270
1250 C=C1:IFA(C,4)=LTHEN1300
1260 GOSUB9340:PRINT"isn't here!"
1270 PRINT"You see two burly policemen approaching.";
1280 IFRND(1)>.1THEN1290
1285 GOSUB9050:GOTO1140
1290 PRINT"You manage to escapt out the back.":GOTO1140
1300 PRINT:GOSUB9630
1302 IFA(C,2)=1THEN1900
1304 IFRND(1)>.5THEN1530
1305 ONA(C,2)+1GOTO1310,1360,1320,1360,1340
1310 R=50:GOTO1330
1320 R=5
1330 IFR<=RND(0)*100THEN1360
1340 IFRND(1)>.8THEN1380
1341 R=INT(RND(1)*100)+1:IFR=A(C,3)THEN1341
1345 IFR=CTHEN1341
1350 GOTO1370
1360 R=A(C,3)
1370 IFR>0THEN1390
1380 PRINT"'I don't know anything, Mr. Bond -":PRINT"honest!'":GOTO1490
1390 IFR=PTHEN1340
1400 PRINT"'Go and see agent #"R"in ";
1410 ONA(C,2)+1GOTO1420,1470,1430,1450,1450
1420 L1=50:GOTO1440
1430 L1=5
1440 IFL1<=RND(0)*100THEN1470
1450 L1=INT(RND(1)*10)+1:IFL1=LTHEN1450
1460 GOTO1480
1470 L1=A(R,4)
1480 PRINTL$(L1);"'";:IFA(C,2)=1THEN1200
1490 PRINT:PRINT"Do you believe that? ";
1500 Q$=INPUT$(1):IFQ$="Y"ORQ$="y"THEN1140
1510 IFA(C,1)=1THEN1515
1512 GOSUB9350:GOTO1630
1515 S=S-200' Provocation penalty
1520 PRINT"You attack him!":GOSUB9300:GOTO1630
1530 '  Second questioning
1540 A=INT(A(C,1)*A(C,2)*L*RND(0))+1
1545 IFA>7THEN1270
1550 ONAGOTO1560,1380,1340,1800,1610,1710,1270
1560 IFA(C,1)=0THEN1700
1570 GOTO1800
1610 PRINT"Suddenly, ";:GOSUB9340:PRINT" attacks you!"
1620 GOSUB9300
1630 ONF+1GOTO1700,1650,1640,1340
1640 PRINT"You lose!"P"had the plans all the time.":END
1650 IFL>=9THENGOSUB9130
1660 PRINT"You wake to find yourself sprawled in   the rubbish of a filthy alley.  You are":
1680 PRINT"bleeding and have many bruises."
1690 A(C,4)=INT(RND(1)*10)+1:S=S-250:GOTO1140
1700 PRINT"'I give in!' says agent #"C
1710 IFC<>A(C,3)THEN1750
1720 PRINT"'I've got the plans here!'"
1730 PRINT:PRINT"YOU WIN!"
1740 PRINT:PRINT"YOUR SCORE WAS"S:END
1750 IFA(C,2)<>4THEN1770
1760 IFRND(1)<.1THEN1340
1770 IFA(C,3)=0THEN1380
1780 PRINT"'See agent #"A(C,3)"in "L$(A(A(C,3),4))"'"
1790 GOTO1140
1800 PRINT"Suddenly, ";:GOSUB9340:PRINT"runs. You chase after";:GOSUB9780
1820 IFRND(1)>.3THEN1870
1830 PRINT"but lose";:GOSUB9780:PRINT"in a maze of alleys."
1840 PRINT"Tough luck!  You guess that it won't be"
1850 PRINT"long before";:GOSUB9340:PRINT"takes a plane out."
1860 A(C,4)=INT(RND(1)*10)+1:S=S-50:GOTO1140
1870 PRINT"and catch up on a parking lot.":GOTO1700
1900 '  British agent
1910 INPUT"What's the password";Q$
1920 IFP$<>Q$THEN1310
1925 IFL=1THEN1950
1930 PRINT:PRINT"'Welcome to "L$(L)", Mr. Bond. "
1940 PRINT"London told me that you were coming.'"
1950 IFC=A(C,3)THEN1720
1960 PRINT"Would you like a list of agents here? "
1970 Q$=INPUT$(1):IFQ$="Y"ORQ$="y"THENZ=L:GOSUB9540
1980 IFA(C,3)<>0THEN1360
2010 PRINT"I haven't heard a word about those plans - not a whisper!":GOTO1140
8000 CLS:PRINT"In this game you take the place of JamesBond, British agent 007.  It is your"
8020 PRINT"job to trace the whereabouts  of  some  highly secret plans stolen from a"
8035 PRINT"foreign power.  To do that you will     require a combination of intellingence,"
8050 PRINT"strength, and luck.":GOSUB8500
8055 PRINT"There are 100 suspected secret agents toconsider.  They are British, American,"
8070 PRINT"Russian, or local and neutral, scattered through 10 cities about the world.
8080 PRINT"(Pencil and paper will be handy.)  To   question a suspected agent, you must"
8090 PRINT"of course be in the same city.":GOSUB8500
8095 PRINT"Agents may tell the truth or lie.":PRINT"Russian agents will ALWAYS lie and"
8100 PRINT"British agents will ALWAYS tell the":PRINT"the truth.  Others may do either.  You"
8110 PRINT"will not know at first what sort of     agent they are, nor whether they are"
8120 PRINT"lying or telling the truth.":GOSUB8500:PRINT"If you do  not believe them you may
8130 PRINT"attack them  (unless they are women),   but BEWARE! - you may lose the fight"
8140 PRINT"and be beaten up or even killed.  Any   agent who beats you up will immediately"
8150 PRINT"depart for another city.  To question   an agent, simply type his or her"
8160 PRINT"number. ";:GOSUB8500:PRINT"To change cities, type 0.":PRINT"You cannot question the same suspect"
8170 PRINT"again immediately,  but may come back   later.  If you ask for someone who"
8180 PRINT"doesn't live in a particular city, the  police are going to get interested in"
8190 PRINT"you, so be careful!":GOSUB8500:PRINT"Other little surprises are in store but"
8200 PRINT"if you keep your wits, you will be able to unravel the truth from the lies and"
8210 PRINT"find the secret stolen plans.":PRINT" Good luck!":PRINT
8500 PRINT"  Press any key...";:A$=INPUT$(1):CLS:RETURN
9000 A=INT(RND(1)*100)+1:IFA(A,Z)<>0THEN9000
9010 RETURN
9050 PRINT"Policemen pour out of the woodwork."
9060 IFL<=8THEN9080
9070 PRINT"Remember that you are in a communist    country."
9080 PRINT"Do you resist arrest? (Y/N) ";:Q$=INPUT$(1):IFQ$="N"ORQ$="n"THENPRINT"You are taken to ";:GOTO9140
9100 GOSUB9720:ONF+1GOTO9120,9130,9290
9120 PRINT"Tough luck!":GOTO1640
9130 PRINT"When you wake up, you find yourself in ";
9140 PRINT"a bare cell.":GOSUB8500
9150 PRINT"A guard enters. ";
9160 IFL<=4THEN9270
9170 ONINT(RND(1)*4)+1GOTO9180,9200,9210,9210
9180 PRINT"'I'm working for British Intelligence.'":GOTO9240
9200 PRINT"'I work for the American CIA', ";:GOTO9240
9210 PRINT"'I've ze message for you,'  he says,    'from someone called EMM.  'E say you   are fired!":GOTO1640
9240 PRINT"he says. 'I've come to get you away.'"
9250 PRINT"A couple of hours later you are safe.":F=0:RETURN
9270 PRINT"'Come one, you!' he says, 'Somebody up  there likes you - you've just been      bailed out!'":F=0
9290 RETURN
9300 PRINT"The struggle rages all over, using any  and every weapon imaginable - fists,    boots, daggers, guns, karate, judo.     Your opponent quickly gets the upper    hand, ";:GOSUB8500
9310 F=INT(RND(1)*100)+1:IFF>98THENF=2:PRINT"and kills you!":RETURN
9320 IFF>90THENF=1:PRINT"and knocks you out!":RETURN
9330 F=0:PRINT"but you get";
9332 GOSUB9780:PRINT"in a stranglehold.":RETURN
9340 IFA(C,1)=0THENPRINT" she ";:RETURN
9341 PRINT" he ";:RETURN
9350 PRINTC" says softly, 'The only plans that I've got, James, you don't need a blueprint for.'"
9354 PRINT"She kisses you warmly.  Do you respond?"
9358 Q$=INPUT$(1):IFQ$="Y"ORQ$="y"THEN9420
9360 IFA(C,2)<=2THEN9400
9370 PRINT"She turns nasty.  Drawing a dagger from her stocking, she attacks you."
9390 GOTO9300
9400 F=3:RETURN
9420 IFA(C,2)<=2THEN9500
9430 PRINT"CHUMP!  She was a Russian agent.  While you were sleeping, she ";:IFRND(1)>.2THEN9480
9460 PRINT"cut your throat. (Ever so gently, of course!)":GOTO1640
9480 F=1:PRINT"lovingly jabbed you with knock-out drops.":RETURN
9500 PRINT"At breakfast the next morning she tells you ";
9510 Z=ABS(A(C,3)):IFC=PTHEN1720
9515 IFA(C,3)=0THENPRINT"she knows nothing."
9520 F=0:RETURN
9540 FORX=1TO100:IFRND(1)<.1THEN9560
9550 IFA(X,4)=ZTHENPRINTX;
9560 NEXT:PRINT:PRINT:RETURN
9570 ONA(R,2)+1GOTO9580,9590,9600,9610,9620
9580 PRINT"UNKNOWN";:RETURN
9590 PRINT"BRITISH";:RETURN
9600 PRINT"AMERICAN";:RETURN
9610 PRINT"LOCAL";:RETURN
9620 PRINT"RUSSIAN";:RETURN
9630 '  Describe agent
9640 PRINT"The agent is a ";
9650 IFA(C,1)=1THEN9670
9660 PRINT"glamorous young woman.":RETURN
9670 IFC=INT(C/3)*3THEN9700
9680 IFC=INT(C/3)*3+1THEN9710
9690 PRINT"scruffy old man.":RETURN
9700 PRINT"respectable business man.";:RETURN
9710 PRINT"hefty thug.":RETURN
9720 PRINT"They attack you from all sides.";:F=L+INT(RND(1)*10)+1
9740 IFF=13THENF=2:PRINT"You are killed!":RETURN
9750 IFF<5THENF=0:PRINT"You escape through a window.":RETURN
9760 F=1:PRINT"You are knocked out......":RETURN
9780 IFA(C,1)=1THENPRINT" him ";:RETURN
9790 PRINT" her ";:RETURN